Initial commit of Arduino libraries

RadioLib/examples/RF69/RF69_Receive_AES/RF69_Receive_AES.ino

@@ -0,0 +1,96 @@
+/*
+  RadioLib RF69 Receive with AES Example
+
+  This example receives packets using RF69 FSK radio module.
+  Packets are decrypted using hardware AES.
+  NOTE: When using address filtering, the address byte is NOT encrypted!
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set AES key that will be used to decrypt the packet
+  // NOTE: the key must be exactly 16 bytes long!
+  uint8_t key[] = {0x00, 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07,
+                   0x08, 0x09, 0x0A, 0x0B, 0x0C, 0x0D, 0x0E, 0x0F};
+  radio.setAESKey(key);
+
+  // enable AES encryption
+  radio.enableAES();
+
+  // AES encryption can also be disabled
+  /*
+    radio.disableAES();
+  */
+}
+
+void loop() {
+  Serial.print(F("[RF69] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[RF69] Data:\t\t"));
+    Serial.println(str);
+
+  } else if (state == RADIOLIB_ERR_RX_TIMEOUT) {
+    // timeout occurred while waiting for a packet
+    Serial.println(F("timeout!"));
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}

RadioLib/examples/RF69/RF69_Receive_Address/RF69_Receive_Address.ino

@@ -0,0 +1,125 @@
+/*
+  RadioLib RF69 Receive with Address Example
+
+  This example receives packets using RF69 FSK radio module.
+  Packets can have 1-byte address of the destination node.
+  After setting node (or broadcast) address, this node will
+  automatically filter out any packets that do not contain
+  either node address or broadcast address.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set node address
+  // NOTE: calling this method will automatically enable
+  // address filtering (node address only)
+  Serial.print(F("[RF69] Setting node address ... "));
+  state = radio.setNodeAddress(0x02);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set broadcast address
+  // NOTE: calling this method will automatically enable
+  //       address filtering (node or broadcast address)
+  Serial.print(F("[RF69] Setting broadcast address ... "));
+  state = radio.setBroadcastAddress(0xFF);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // address filtering can also be disabled
+  // NOTE: calling this method will also erase previously set
+  // node and broadcast address
+  /*
+    Serial.print(F("[RF69] Disabling address filtering ... "));
+    state == radio.disableAddressFiltering();
+    if(state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+}
+
+void loop() {
+  Serial.print(F("[RF69] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[RF69] Data:\t\t"));
+    Serial.println(str);
+
+  } else if (state == RADIOLIB_ERR_RX_TIMEOUT) {
+    // timeout occurred while waiting for a packet
+    Serial.println(F("timeout!"));
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}

RadioLib/examples/RF69/RF69_Receive_Blocking/RF69_Receive_Blocking.ino

@@ -0,0 +1,97 @@
+/*
+  RadioLib RF69 Blocking Receive Example
+
+  This example receives packets using RF69 FSK radio module.
+  To successfully receive data, the following settings have to be the same
+  on both transmitter and receiver:
+  - carrier frequency
+  - bit rate
+  - frequency deviation
+  - sync word
+
+  Using blocking receive is not recommended, as it will lead
+  to significant amount of timeouts, inefficient use of processor
+  time and can miss some packets!
+  Instead, interrupt receive is recommended.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  Serial.print(F("[RF69] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[RF69] Data:\t\t"));
+    Serial.println(str);
+
+    // print RSSI (Received Signal Strength Indicator)
+    // of the last received packet
+    Serial.print(F("[RF69] RSSI:\t\t"));
+    Serial.print(radio.getRSSI());
+    Serial.println(F(" dBm"));
+
+  } else if (state == RADIOLIB_ERR_RX_TIMEOUT) {
+    // timeout occurred while waiting for a packet
+    Serial.println(F("timeout!"));
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}

RadioLib/examples/RF69/RF69_Receive_Interrupt/RF69_Receive_Interrupt.ino

@@ -0,0 +1,131 @@
+/*
+  RadioLib RF69 Receive with Interrupts Example
+
+  This example listens for FSK transmissions and tries to
+  receive them. Once a packet is received, an interrupt is
+  triggered.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+// flag to indicate that a packet was received
+volatile bool receivedFlag = false;
+
+// this function is called when a complete packet
+// is received by the module
+// IMPORTANT: this function MUST be 'void' type
+//            and MUST NOT have any arguments!
+#if defined(ESP8266) || defined(ESP32)
+  ICACHE_RAM_ATTR
+#endif
+void setFlag(void) {
+  // we got a packet, set the flag
+  receivedFlag = true;
+}
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set the function that will be called
+  // when new packet is received
+  radio.setPacketReceivedAction(setFlag);
+
+  // start listening for packets
+  Serial.print(F("[RF69] Starting to listen ... "));
+  state = radio.startReceive();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // if needed, 'listen' mode can be disabled by calling
+  // any of the following methods:
+  //
+  // radio.standby()
+  // radio.sleep()
+  // radio.transmit();
+  // radio.receive();
+  // radio.readData();
+}
+
+void loop() {
+  // check if the flag is set
+  if(receivedFlag) {
+    // reset flag
+    receivedFlag = false;
+
+    // you can read received data as an Arduino String
+    String str;
+    int state = radio.readData(str);
+
+    // you can also read received data as byte array
+    /*
+      byte byteArr[8];
+      int numBytes = radio.getPacketLength();
+      int state = radio.readData(byteArr, numBytes);
+    */
+
+    if (state == RADIOLIB_ERR_NONE) {
+      // packet was successfully received
+      Serial.println(F("[RF69] Received packet!"));
+
+      // print data of the packet
+      Serial.print(F("[RF69] Data:\t\t"));
+      Serial.println(str);
+
+      // print RSSI (Received Signal Strength Indicator)
+      // of the last received packet
+      Serial.print(F("[RF69] RSSI:\t\t"));
+      Serial.print(radio.getRSSI());
+      Serial.println(F(" dBm"));
+
+    } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+      // packet was received, but is malformed
+      Serial.println(F("CRC error!"));
+
+    } else {
+      // some other error occurred
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+
+    }
+
+    // put module back to listen mode
+    radio.startReceive();
+  }
+}

RadioLib/examples/RF69/RF69_Settings/RF69_Settings.ino

@@ -0,0 +1,143 @@
+/*
+  RadioLib RF69 Settings Example
+
+  This example shows how to change all the properties of RF69 radio.
+  RadioLib currently supports the following settings:
+  - pins (SPI slave select, digital IO 0, digital IO 1)
+  - carrier frequency
+  - bit rate
+  - receiver bandwidth
+  - allowed frequency deviation
+  - output power during transmission
+  - sync word
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio1 = new Module(10, 2, 3);
+
+// second CC1101 has different connections:
+// CS pin:    9
+// DIO0 pin:  4
+// RESET pin: 5
+RF69 radio2 = new Module(9, 4, 5);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio3 = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio1.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize RF69 with non-default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  // carrier frequency:                   868.0 MHz
+  // bit rate:                            300.0 kbps
+  // frequency deviation:                 60.0 kHz
+  // Rx bandwidth:                        250.0 kHz
+  // output power:                        17 dBm
+  // preamble length:                     32 bits
+  state = radio2.begin(868.0, 300.0, 60.0, 250.0, 17, 32);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // you can also change the settings at runtime
+  // and check if the configuration was changed successfully
+
+  // set carrier frequency to 433.5 MHz
+  if (radio1.setFrequency(433.5) == RADIOLIB_ERR_INVALID_FREQUENCY) {
+    Serial.println(F("[RF69] Selected frequency is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // set bit rate to 100.0 kbps
+  state = radio1.setBitRate(100.0);
+  if (state == RADIOLIB_ERR_INVALID_BIT_RATE) {
+    Serial.println(F("[RF69] Selected bit rate is invalid for this module!"));
+    while (true) { delay(10); }
+  } else if (state == RADIOLIB_ERR_INVALID_BIT_RATE_BW_RATIO) {
+    Serial.println(F("[RF69] Selected bit rate to bandwidth ratio is invalid!"));
+    Serial.println(F("[RF69] Increase receiver bandwidth to set this bit rate."));
+    while (true) { delay(10); }
+  }
+
+  // set receiver bandwidth to 250.0 kHz
+  state = radio1.setRxBandwidth(250.0);
+  if (state == RADIOLIB_ERR_INVALID_RX_BANDWIDTH) {
+    Serial.println(F("[RF69] Selected receiver bandwidth is invalid for this module!"));
+    while (true) { delay(10); }
+  } else if (state == RADIOLIB_ERR_INVALID_BIT_RATE_BW_RATIO) {
+    Serial.println(F("[RF69] Selected bit rate to bandwidth ratio is invalid!"));
+    Serial.println(F("[RF69] Decrease bit rate to set this receiver bandwidth."));
+    while (true) { delay(10); }
+  }
+
+  // set allowed frequency deviation to 10.0 kHz
+  if (radio1.setFrequencyDeviation(10.0) == RADIOLIB_ERR_INVALID_FREQUENCY_DEVIATION) {
+    Serial.println(F("[RF69] Selected frequency deviation is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // set output power to 2 dBm
+  if (radio1.setOutputPower(2) == RADIOLIB_ERR_INVALID_OUTPUT_POWER) {
+    Serial.println(F("[RF69] Selected output power is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // up to 8 bytes can be set as sync word
+  // NOTE: sync word must not contain any zero bytes
+  // set sync word to 0x0123456789ABCDEF
+  uint8_t syncWord[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+  if (radio1.setSyncWord(syncWord, 8) == RADIOLIB_ERR_INVALID_SYNC_WORD) {
+    Serial.println(F("[RF69] Selected sync word is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  Serial.println(F("[RF69] All settings changed successfully!"));
+
+  // RF69 can also measure temperature (roughly)
+  // to get correct temperature measurements, the sensor must be calibrated
+  // at ambient temperature
+  radio1.setAmbientTemperature(25); // replace 25 with your ambient temperature
+}
+
+void loop() {
+  // measure temperature
+  Serial.print(F("[RF69] Measured temperature: "));
+  Serial.print(radio1.getTemperature());
+  Serial.println(F(" deg C"));
+
+  // wait 100 ms before the next measurement
+  delay(100);
+}

RadioLib/examples/RF69/RF69_Transmit_AES/RF69_Transmit_AES.ino

@@ -0,0 +1,90 @@
+/*
+  RadioLib RF69 Transmit with AES Example
+
+  This example transmits packets using RF69 FSK radio module.
+  Packets are encrypted using hardware AES.
+  NOTE: When using address filtering, the address byte is NOT encrypted!
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set AES key to encrypt the packet
+  // NOTE: the key must be exactly 16 bytes long!
+  uint8_t key[] = {0x00, 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07,
+                   0x08, 0x09, 0x0A, 0x0B, 0x0C, 0x0D, 0x0E, 0x0F};
+  radio.setAESKey(key);
+
+  // enable AES encryption
+  radio.enableAES();
+
+  // AES encryption can also be disabled
+  /*
+    radio.disableAES();
+  */
+}
+
+void loop() {
+  Serial.print(F("[RF69] Transmitting packet ... "));
+
+  // you can transmit C-string or Arduino string up to 64 characters long
+  int state = radio.transmit("Hello World!");
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+    int state = radio.transmit(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // the packet was successfully transmitted
+    Serial.println(F("success!"));
+
+  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
+    // the supplied packet was longer than 64 bytes
+    Serial.println(F("too long!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait for a second before transmitting again
+  delay(1000);
+}

RadioLib/examples/RF69/RF69_Transmit_Address/RF69_Transmit_Address.ino

@@ -0,0 +1,130 @@
+/*
+  RadioLib RF69 Transmit to Address Example
+
+  This example transmits packets using RF69 FSK radio module.
+  Packets can have 1-byte address of the destination node.
+  After setting node (or broadcast) address, this node will
+  automatically filter out any packets that do not contain
+  either node address or broadcast address.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set node address
+  // NOTE: calling this method will automatically enable
+  // address filtering (node address only)
+  Serial.print(F("[RF69] Setting node address ... "));
+  state = radio.setNodeAddress(0x01);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set broadcast address
+  // NOTE: calling this method will automatically enable
+  // address filtering (node or broadcast address)
+  Serial.print(F("[RF69] Setting broadcast address ... "));
+  state = radio.setBroadcastAddress(0xFF);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // address filtering can also be disabled
+  // NOTE: calling this method will also erase previously set
+  //       node and broadcast address
+  /*
+    Serial.print(F("[RF69] Disabling address filtering ... "));
+    state = radio.disableAddressFiltering();
+    if(state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+}
+
+void loop() {
+  Serial.print(F("[RF69] Transmitting packet ... "));
+
+  // transmit C-string or Arduino string to node with address 0x02
+  int state = radio.transmit("Hello World!", 0x02);
+
+  // transmit byte array to node with address 0x02
+  /*
+  byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+  int state = radio.transmit(byteArr, 8, 0x02);
+  */
+
+  // transmit C-string or Arduino string in broadcast mode
+  /*
+    int state = radio.transmit("Hello World!", 0xFF);
+  */
+
+  // transmit byte array in broadcast mode
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+    int state = radio.transmit(byteArr, 8, 0xFF);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // the packet was successfully transmitted
+    Serial.println(F("success!"));
+
+  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
+    // the supplied packet was longer than 64 bytes
+    Serial.println(F("too long!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait for a second before transmitting again
+  delay(1000);
+}

RadioLib/examples/RF69/RF69_Transmit_Blocking/RF69_Transmit_Blocking.ino

@@ -0,0 +1,103 @@
+/*
+  RadioLib RF69 Blocking Transmit Example
+
+  This example transmits packets using RF69 FSK radio module.
+  Each packet contains up to 64 bytes of data, in the form of:
+  - Arduino String
+  - null-terminated char array (C-string)
+  - arbitrary binary data (byte array)
+
+  Using blocking transmit is not recommended, as it will lead
+  to inefficient use of processor time!
+  Instead, interrupt transmit is recommended.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // NOTE: some RF69 modules use high power output,
+  //       those are usually marked RF69H(C/CW).
+  //       To configure RadioLib for these modules,
+  //       you must call setOutputPower() with
+  //       second argument set to true.
+  /*
+    Serial.print(F("[RF69] Setting high power module ... "));
+    state = radio.setOutputPower(20, true);
+    if (state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+}
+
+// counter to keep track of transmitted packets
+int count = 0;
+
+void loop() {
+  Serial.print(F("[RF69] Transmitting packet ... "));
+
+  // you can transmit C-string or Arduino string up to 64 characters long
+  String str = "Hello World! #" + String(count++);
+  int state = radio.transmit(str);
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+    int state = radio.transmit(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // the packet was successfully transmitted
+    Serial.println(F("success!"));
+
+  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
+    // the supplied packet was longer than 64 bytes
+    Serial.println(F("too long!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait for a second before transmitting again
+  delay(1000);
+}

RadioLib/examples/RF69/RF69_Transmit_Interrupt/RF69_Transmit_Interrupt.ino

@@ -0,0 +1,149 @@
+/*
+  RadioLib RF69 Transmit with Interrupts Example
+
+  This example transmits FSK packets with one second delays
+  between them. Each packet contains up to 64 bytes
+  of data, in the form of:
+  - Arduino String
+  - null-terminated char array (C-string)
+  - arbitrary binary data (byte array)
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#rf69sx1231
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// RF69 has the following connections:
+// CS pin:    10
+// DIO0 pin:  2
+// RESET pin: 3
+RF69 radio = new Module(10, 2, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+// save transmission state between loops
+int transmissionState = RADIOLIB_ERR_NONE;
+
+// flag to indicate that a packet was sent
+volatile bool transmittedFlag = false;
+
+// this function is called when a complete packet
+// is transmitted by the module
+// IMPORTANT: this function MUST be 'void' type
+//            and MUST NOT have any arguments!
+#if defined(ESP8266) || defined(ESP32)
+  ICACHE_RAM_ATTR
+#endif
+void setFlag(void) {
+  // we sent a packet, set the flag
+  transmittedFlag = true;
+}
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize RF69 with default settings
+  Serial.print(F("[RF69] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set the function that will be called
+  // when packet transmission is finished
+  radio.setPacketSentAction(setFlag);
+
+  // NOTE: some RF69 modules use high power output,
+  //       those are usually marked RF69H(C/CW).
+  //       To configure RadioLib for these modules,
+  //       you must call setOutputPower() with
+  //       second argument set to true.
+  /*
+    Serial.print(F("[RF69] Setting high power module ... "));
+    state = radio.setOutputPower(20, true);
+    if (state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+
+  // start transmitting the first packet
+  Serial.print(F("[RF69] Sending first packet ... "));
+
+  // you can transmit C-string or Arduino string up to
+  // 64 characters long
+  transmissionState = radio.startTransmit("Hello World!");
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67,
+                      0x89, 0xAB, 0xCD, 0xEF};
+    state = radio.startTransmit(byteArr, 8);
+  */
+}
+
+// counter to keep track of transmitted packets
+int count = 0;
+
+void loop() {
+  // check if the previous transmission finished
+  if(transmittedFlag) {
+    // reset flag
+    transmittedFlag = false;
+
+    if (transmissionState == RADIOLIB_ERR_NONE) {
+      // packet was successfully sent
+      Serial.println(F("transmission finished!"));
+
+      // NOTE: when using interrupt-driven transmit method,
+      //       it is not possible to automatically measure
+      //       transmission data rate using getDataRate()
+
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(transmissionState);
+
+    }
+
+    // clean up after transmission is finished
+    // this will ensure transmitter is disabled,
+    // RF switch is powered down etc.
+    radio.finishTransmit();
+
+    // wait a second before transmitting again
+    delay(1000);
+
+    // send another one
+    Serial.print(F("[RF69] Sending another packet ... "));
+
+    // you can transmit C-string or Arduino string up to
+    // 64 characters long
+    String str = "Hello World! #" + String(count++);
+    transmissionState = radio.startTransmit(str);
+
+    // you can also transmit byte array up to 64 bytes long
+    /*
+      byte byteArr[] = {0x01, 0x23, 0x45, 0x67,
+                        0x89, 0xAB, 0xCD, 0xEF};
+      transmissionState = radio.startTransmit(byteArr, 8);
+    */
+  }
+}