Initial commit of Arduino libraries

RadioLib/examples/CC1101/CC1101_Receive_Address/CC1101_Receive_Address.ino

@@ -0,0 +1,124 @@
+/*
+  RadioLib CC1101 Receive with Address Example
+
+  This example receives packets using CC1101 FSK radio
+  module. Packets can have 1-byte address of the
+  destination node. After setting node address, this node
+  will automatically filter out any packets that do not
+  contain either node address or broadcast addresses.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3 (optional)
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set node address
+  // NOTE: Calling this method will automatically enable
+  //       address filtering. CC1101 also allows to set
+  //       number of broadcast address (0/1/2).
+  //       The following sets one broadcast address 0x00.
+  //       When setting two broadcast addresses, 0x00 and
+  //       0xFF will be used.
+  Serial.print(F("[CC1101] Setting node address ... "));
+  state = radio.setNodeAddress(0x01, 1);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // address filtering can also be disabled
+  // NOTE: Calling this method will also erase previously
+  //       set node address
+  /*
+    Serial.print(F("[CC1101] Disabling address filtering ... "));
+    state == radio.disableAddressFiltering();
+    if(state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+}
+
+void loop() {
+  Serial.print(F("[CC1101] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[CC1101] Data:\t\t"));
+    Serial.println(str);
+
+    // print RSSI (Received Signal Strength Indicator)
+    // of the last received packet
+    Serial.print(F("[CC1101] RSSI:\t\t"));
+    Serial.print(radio.getRSSI());
+    Serial.println(F(" dBm"));
+
+    // print LQI (Link Quality Indicator)
+    // of the last received packet, lower is better
+    Serial.print(F("[CC1101] LQI:\t\t"));
+    Serial.println(radio.getLQI());
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}

RadioLib/examples/CC1101/CC1101_Receive_Blocking/CC1101_Receive_Blocking.ino

@@ -0,0 +1,103 @@
+/*
+  RadioLib CC1101 Blocking Receive Example
+
+  This example receives packets using CC1101 FSK radio module.
+  To successfully receive data, the following settings have to be the same
+  on both transmitter and receiver:
+  - carrier frequency
+  - bit rate
+  - frequency deviation
+  - sync word
+
+  Using blocking receive is not recommended, as it will lead
+  to significant amount of timeouts, inefficient use of processor
+  time and can some miss packets!
+  Instead, interrupt receive is recommended.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3 (optional)
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  Serial.print(F("[CC1101] Waiting for incoming transmission ... "));
+
+  // you can receive data as an Arduino String
+  String str;
+  int state = radio.receive(str);
+
+  // you can also receive data as byte array
+  /*
+    byte byteArr[8];
+    int state = radio.receive(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // packet was successfully received
+    Serial.println(F("success!"));
+
+    // print the data of the packet
+    Serial.print(F("[CC1101] Data:\t\t"));
+    Serial.println(str);
+
+    // print RSSI (Received Signal Strength Indicator)
+    // of the last received packet
+    Serial.print(F("[CC1101] RSSI:\t\t"));
+    Serial.print(radio.getRSSI());
+    Serial.println(F(" dBm"));
+
+    // print LQI (Link Quality Indicator)
+    // of the last received packet, lower is better
+    Serial.print(F("[CC1101] LQI:\t\t"));
+    Serial.println(radio.getLQI());
+
+  } else if (state == RADIOLIB_ERR_RX_TIMEOUT) {
+    // timeout occurred while waiting for a packet
+    Serial.println(F("timeout!"));
+
+  } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+    // packet was received, but is malformed
+    Serial.println(F("CRC error!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+}

RadioLib/examples/CC1101/CC1101_Receive_Interrupt/CC1101_Receive_Interrupt.ino

@@ -0,0 +1,145 @@
+/*
+  RadioLib CC1101 Receive with Interrupts Example
+
+  This example listens for FSK transmissions and tries to
+  receive them. Once a packet is received, an interrupt is
+  triggered.
+
+  To successfully receive data, the following settings have to be the same
+  on both transmitter and receiver:
+  - carrier frequency
+  - bit rate
+  - frequency deviation
+  - sync word
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3 (optional)
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+// flag to indicate that a packet was received
+volatile bool receivedFlag = false;
+
+// this function is called when a complete packet
+// is received by the module
+// IMPORTANT: this function MUST be 'void' type
+//            and MUST NOT have any arguments!
+#if defined(ESP8266) || defined(ESP32)
+  ICACHE_RAM_ATTR
+#endif
+void setFlag(void) {
+  // we got a packet, set the flag
+  receivedFlag = true;
+}
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set the function that will be called
+  // when new packet is received
+  radio.setPacketReceivedAction(setFlag);
+
+  // start listening for packets
+  Serial.print(F("[CC1101] Starting to listen ... "));
+  state = radio.startReceive();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // if needed, 'listen' mode can be disabled by calling
+  // any of the following methods:
+  //
+  // radio.standby()
+  // radio.sleep()
+  // radio.transmit();
+  // radio.receive();
+  // radio.readData();
+}
+
+void loop() {
+  // check if the flag is set
+  if(receivedFlag) {
+    // reset flag
+    receivedFlag = false;
+
+    // you can read received data as an Arduino String
+    String str;
+    int state = radio.readData(str);
+
+    // you can also read received data as byte array
+    /*
+      byte byteArr[8];
+      int numBytes = radio.getPacketLength();
+      int state = radio.readData(byteArr, numBytes);
+    */
+
+    if (state == RADIOLIB_ERR_NONE) {
+      // packet was successfully received
+      Serial.println(F("[CC1101] Received packet!"));
+
+      // print data of the packet
+      Serial.print(F("[CC1101] Data:\t\t"));
+      Serial.println(str);
+
+      // print RSSI (Received Signal Strength Indicator)
+      // of the last received packet
+      Serial.print(F("[CC1101] RSSI:\t\t"));
+      Serial.print(radio.getRSSI());
+      Serial.println(F(" dBm"));
+
+      // print LQI (Link Quality Indicator)
+      // of the last received packet, lower is better
+      Serial.print(F("[CC1101] LQI:\t\t"));
+      Serial.println(radio.getLQI());
+
+    } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
+      // packet was received, but is malformed
+      Serial.println(F("CRC error!"));
+
+    } else {
+      // some other error occurred
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+
+    }
+
+    // put module back to listen mode
+    radio.startReceive();
+  }
+
+}

RadioLib/examples/CC1101/CC1101_Settings/CC1101_Settings.ino

@@ -0,0 +1,125 @@
+/*
+  RadioLib CC1101 Settings Example
+
+  This example shows how to change all the properties of RF69 radio.
+  RadioLib currently supports the following settings:
+  - pins (SPI slave select, digital IO 0, digital IO 1)
+  - carrier frequency
+  - bit rate
+  - receiver bandwidth
+  - allowed frequency deviation
+  - output power during transmission
+  - sync word
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3 (optional)
+CC1101 radio1 = new Module(10, 2, RADIOLIB_NC, 3);
+
+// second CC1101 has different connections:
+// CS pin:    9
+// GDO0 pin:  4
+// RST pin:   unused
+// GDO2 pin:  5 (optional)
+CC1101 radio2 = new Module(9, 4, RADIOLIB_NC, 5);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio3 = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio1.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize CC1101 with non-default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  // carrier frequency:                   434.0 MHz
+  // bit rate:                            32.0 kbps
+  // frequency deviation:                 60.0 kHz
+  // Rx bandwidth:                        250.0 kHz
+  // output power:                        7 dBm
+  // preamble length:                     32 bits
+  state = radio2.begin(434.0, 32.0, 60.0, 250.0, 7, 32);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // you can also change the settings at runtime
+  // and check if the configuration was changed successfully
+
+  // set carrier frequency to 433.5 MHz
+  if (radio1.setFrequency(433.5) == RADIOLIB_ERR_INVALID_FREQUENCY) {
+    Serial.println(F("[CC1101] Selected frequency is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // set bit rate to 100.0 kbps
+  state = radio1.setBitRate(100.0);
+  if (state == RADIOLIB_ERR_INVALID_BIT_RATE) {
+    Serial.println(F("[CC1101] Selected bit rate is invalid for this module!"));
+    while (true) { delay(10); }
+  } else if (state == RADIOLIB_ERR_INVALID_BIT_RATE_BW_RATIO) {
+    Serial.println(F("[CC1101] Selected bit rate to bandwidth ratio is invalid!"));
+    Serial.println(F("[CC1101] Increase receiver bandwidth to set this bit rate."));
+    while (true) { delay(10); }
+  }
+
+  // set receiver bandwidth to 250.0 kHz
+  if (radio1.setRxBandwidth(250.0) == RADIOLIB_ERR_INVALID_RX_BANDWIDTH) {
+    Serial.println(F("[CC1101] Selected receiver bandwidth is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // set allowed frequency deviation to 10.0 kHz
+  if (radio1.setFrequencyDeviation(10.0) == RADIOLIB_ERR_INVALID_FREQUENCY_DEVIATION) {
+    Serial.println(F("[CC1101] Selected frequency deviation is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // set output power to 5 dBm
+  if (radio1.setOutputPower(5) == RADIOLIB_ERR_INVALID_OUTPUT_POWER) {
+    Serial.println(F("[CC1101] Selected output power is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+  // 2 bytes can be set as sync word
+  if (radio1.setSyncWord(0x01, 0x23) == RADIOLIB_ERR_INVALID_SYNC_WORD) {
+    Serial.println(F("[CC1101] Selected sync word is invalid for this module!"));
+    while (true) { delay(10); }
+  }
+
+}
+
+void loop() {
+  // nothing here
+}

RadioLib/examples/CC1101/CC1101_Transmit_Address/CC1101_Transmit_Address.ino

@@ -0,0 +1,111 @@
+/*
+  RadioLib CC1101 Transmit to Address Example
+
+  This example transmits packets using CC1101 FSK radio
+  module. Packets can have 1-byte address of the
+  destination node. After setting node address, this node
+  will automatically filter out any packets that do not
+  contain either node address or broadcast addresses.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3 (optional)
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set node address
+  // NOTE: Calling this method will automatically enable
+  //       address filtering. CC1101 also allows to set
+  //       number of broadcast address (0/1/2).
+  //       The following sets one broadcast address 0x00.
+  //       When setting two broadcast addresses, 0x00 and
+  //       0xFF will be used.
+  Serial.print(F("[CC1101] Setting node address ... "));
+  state = radio.setNodeAddress(0x01, 1);
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // address filtering can also be disabled
+  // NOTE: Calling this method will also erase previously
+  //       set node address
+  /*
+    Serial.print(F("[CC1101] Disabling address filtering ... "));
+    state == radio.disableAddressFiltering();
+    if(state == RADIOLIB_ERR_NONE) {
+      Serial.println(F("success!"));
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(state);
+      while (true) { delay(10); }
+    }
+  */
+}
+
+void loop() {
+  Serial.print(F("[CC1101] Transmitting packet ... "));
+
+  // you can transmit C-string or Arduino string up to 64 characters long
+  int state = radio.transmit("Hello World!");
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+    int state = radio.transmit(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // the packet was successfully transmitted
+    Serial.println(F("success!"));
+
+  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
+    // the supplied packet was longer than 255 bytes
+    Serial.println(F("too long!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait for a second before transmitting again
+  delay(1000);
+}

RadioLib/examples/CC1101/CC1101_Transmit_Blocking/CC1101_Transmit_Blocking.ino

@@ -0,0 +1,87 @@
+/*
+  RadioLib CC1101 Blocking Transmit Example
+
+  This example transmits packets using CC1101 FSK radio module.
+  Each packet contains up to 64 bytes of data, in the form of:
+  - Arduino String
+  - null-terminated char array (C-string)
+  - arbitrary binary data (byte array)
+
+  Using blocking transmit is not recommended, as it will lead
+  to inefficient use of processor time!
+  Instead, interrupt transmit is recommended.
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+// counter to keep track of transmitted packets
+int count = 0;
+
+void loop() {
+  Serial.print(F("[CC1101] Transmitting packet ... "));
+
+  // you can transmit C-string or Arduino string up to 64 characters long
+  String str = "Hello World! #" + String(count++);
+  int state = radio.transmit(str);
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x67, 0x89, 0xAB, 0xCD, 0xEF};
+    int state = radio.transmit(byteArr, 8);
+  */
+
+  if (state == RADIOLIB_ERR_NONE) {
+    // the packet was successfully transmitted
+    Serial.println(F("success!"));
+
+  } else if (state == RADIOLIB_ERR_PACKET_TOO_LONG) {
+    // the supplied packet was longer than 64 bytes
+    Serial.println(F("too long!"));
+
+  } else {
+    // some other error occurred
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+
+  }
+
+  // wait for a second before transmitting again
+  delay(1000);
+}

RadioLib/examples/CC1101/CC1101_Transmit_Interrupt/CC1101_Transmit_Interrupt.ino

@@ -0,0 +1,133 @@
+/*
+  RadioLib CC1101 Transmit with Interrupts Example
+
+  This example transmits packets using CC1101 FSK radio module.
+  Once a packet is transmitted, an interrupt is triggered.
+  Each packet contains up to 64 bytes of data, in the form of:
+  - Arduino String
+  - null-terminated char array (C-string)
+  - arbitrary binary data (byte array)
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration#cc1101
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// CC1101 has the following connections:
+// CS pin:    10
+// GDO0 pin:  2
+// RST pin:   unused
+// GDO2 pin:  3
+CC1101 radio = new Module(10, 2, RADIOLIB_NC, 3);
+
+// or detect the pinout automatically using RadioBoards
+// https://github.com/radiolib-org/RadioBoards
+/*
+#define RADIO_BOARD_AUTO
+#include <RadioBoards.h>
+Radio radio = new RadioModule();
+*/
+
+// save transmission state between loops
+int transmissionState = RADIOLIB_ERR_NONE;
+
+// flag to indicate that a packet was sent
+volatile bool transmittedFlag = false;
+
+// this function is called when a complete packet
+// is transmitted by the module
+// IMPORTANT: this function MUST be 'void' type
+//            and MUST NOT have any arguments!
+#if defined(ESP8266) || defined(ESP32)
+  ICACHE_RAM_ATTR
+#endif
+void setFlag(void) {
+  // we sent a packet, set the flag
+  transmittedFlag = true;
+}
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize CC1101 with default settings
+  Serial.print(F("[CC1101] Initializing ... "));
+  int state = radio.begin();
+  if (state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // set the function that will be called
+  // when packet transmission is finished
+  radio.setPacketSentAction(setFlag);
+
+  // start transmitting the first packet
+  Serial.print(F("[CC1101] Sending first packet ... "));
+
+  // you can transmit C-string or Arduino string up to
+  // 64 characters long
+  transmissionState = radio.startTransmit("Hello World!");
+
+  // you can also transmit byte array up to 64 bytes long
+  /*
+    byte byteArr[] = {0x01, 0x23, 0x45, 0x56,
+                      0x78, 0xAB, 0xCD, 0xEF};
+    state = radio.startTransmit(byteArr, 8);
+  */
+}
+
+// counter to keep track of transmitted packets
+int count = 0;
+
+void loop() {
+  // check if the previous transmission finished
+  if(transmittedFlag) {
+    // reset flag
+    transmittedFlag = false;
+
+    if (transmissionState == RADIOLIB_ERR_NONE) {
+      // packet was successfully sent
+      Serial.println(F("transmission finished!"));
+
+      // NOTE: when using interrupt-driven transmit method,
+      //       it is not possible to automatically measure
+      //       transmission data rate using getDataRate()
+
+    } else {
+      Serial.print(F("failed, code "));
+      Serial.println(transmissionState);
+
+    }
+
+    // clean up after transmission is finished
+    // this will ensure transmitter is disabled,
+    // RF switch is powered down etc.
+    radio.finishTransmit();
+
+    // wait a second before transmitting again
+    delay(1000);
+
+    // send another one
+    Serial.print(F("[CC1101] Sending another packet ... "));
+
+    // you can transmit C-string or Arduino string up to
+    // 64 characters long
+    String str = "Hello World! #" + String(count++);
+    transmissionState = radio.startTransmit(str);
+
+    // you can also transmit byte array up to 64 bytes long
+    /*
+      byte byteArr[] = {0x01, 0x23, 0x45, 0x67,
+                        0x89, 0xAB, 0xCD, 0xEF};
+      int state = radio.startTransmit(byteArr, 8);
+    */
+  }
+}