Initial commit of Arduino libraries

RadioLib/examples/AFSK/AFSK_External_Radio/AFSK_External_Radio.ino

@@ -0,0 +1,94 @@
+/*
+  RadioLib AFSK External Radio example
+
+  This example shows how to use your Arduino
+  as modulator for an external analogue FM radio.
+  
+  The example sends APRS position reports with
+  audio modulated as AFSK at 1200 baud using
+  Bell 202 tones. However, any other AFSK
+  protocol (RTTY, SSTV, etc.) may be used as well.
+
+  DO NOT transmit in APRS bands unless
+  you have a ham radio license!
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// create a dummy radio module
+ExternalRadio radio;
+
+// create AFSK client instance using the external radio
+// pin 5 is connected to the radio sound input
+AFSKClient audio(&radio, 5);
+
+// create AX.25 client instance using the AFSK instance
+AX25Client ax25(&audio);
+
+// create APRS client instance using the AX.25 client
+APRSClient aprs(&ax25);
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize AX.25 client
+  Serial.print(F("[AX.25] Initializing ... "));
+  // source station callsign:     "N7LEM"
+  // source station SSID:         0
+  // preamble length:             8 bytes
+  int16_t state = ax25.begin("N7LEM");
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize APRS client
+  Serial.print(F("[APRS] Initializing ... "));
+  // symbol:                      '>' (car)
+  state = aprs.begin('>');
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  Serial.print(F("[APRS] Sending position ... "));
+  
+  // send a location without message or timestamp
+  char destination[] = "N0CALL";
+  char latitude[] = "4911.67N";
+  char longitude[] = "01635.96E";
+  int state = aprs.sendPosition(destination, 0, latitude, longitude);
+  delay(500);
+  
+  // send a location with message and without timestamp
+  char message[] = "I'm here!";
+  state |= aprs.sendPosition(destination, 0, latitude, longitude, message);
+  delay(500);
+  
+  // send a location with message and timestamp
+  char timestamp[] = "093045z";
+  state |= aprs.sendPosition(destination, 0, latitude, longitude, message, timestamp);
+  delay(500);
+
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+  }
+
+  // wait one minute before transmitting again
+  delay(60000);
+}

RadioLib/examples/AFSK/AFSK_Imperial_March/AFSK_Imperial_March.ino

@@ -0,0 +1,107 @@
+/*
+  RadioLib AFSK Imperial March Example
+
+  This example shows how to EXECUTE ORDER 66
+
+  Other modules that can be used for AFSK:
+  - SX127x/RFM9x
+  - RF69
+  - SX1231
+  - CC1101
+  - Si443x/RFM2x
+  - SX126x/LLCC68
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// include the melody
+#include "melody.h"
+
+// SX1278 has the following connections:
+// NSS pin:   10
+// DIO0 pin:  2
+// RESET pin: 9
+// DIO1 pin:  3
+SX1278 radio = new Module(10, 2, 9, 3);
+
+// create AFSK client instance using the FSK module
+// this requires connection to the module direct
+// input pin, here connected to Arduino pin 5
+// SX127x/RFM9x:  DIO2
+// RF69:          DIO2
+// SX1231:        DIO2
+// CC1101:        GDO2
+// Si443x/RFM2x:  GPIO
+// SX126x/LLCC68: DIO2
+AFSKClient audio(&radio, 5);
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize SX1278 with default settings
+  Serial.print(F("[SX1278] Initializing ... "));
+  int state = radio.beginFSK();
+
+  // when using one of the non-LoRa modules for AFSK
+  // (RF69, CC1101,, Si4432 etc.), use the basic begin() method
+  // int state = radio.begin();
+
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize AFSK client
+  Serial.print(F("[AFSK] Initializing ... "));
+  state = audio.begin();
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  Serial.print(F("[AFSK] Executing Order 66 ... "));
+
+  // calculate whole note duration
+  int wholenote = (60000 * 4) / 120;
+
+  // iterate over the melody
+  for(unsigned int note = 0; note < sizeof(melody) / sizeof(melody[0]); note += 2) {
+    // calculate the duration of each note
+    int noteDuration = 0;
+    int divider = melody[note + 1];
+    if(divider > 0) {
+      // regular note, just proceed
+      noteDuration = wholenote / divider;
+    } else if(divider < 0) {
+      // dotted notes are represented with negative durations!!
+      noteDuration = wholenote / abs(divider);
+      noteDuration *= 1.5; // increases the duration in half for dotted notes
+    }
+
+    // we only play the note for 90% of the duration, leaving 10% as a pause
+    audio.tone(melody[note]);
+    delay(noteDuration*0.9);
+    audio.noTone();
+    delay(noteDuration*0.1);
+  }
+
+  Serial.println(F("done!"));
+
+  // wait for a second
+  delay(1000);
+}

RadioLib/examples/AFSK/AFSK_Imperial_March/melody.h

@@ -0,0 +1,128 @@
+/*
+  Note definitions, melody and melody-related functions
+  adapted from https://github.com/robsoncouto/arduino-songs
+  by Robson Couto, 2019
+*/
+
+#define NOTE_B0  31
+#define NOTE_C1  33
+#define NOTE_CS1 35
+#define NOTE_D1  37
+#define NOTE_DS1 39
+#define NOTE_E1  41
+#define NOTE_F1  44
+#define NOTE_FS1 46
+#define NOTE_G1  49
+#define NOTE_GS1 52
+#define NOTE_A1  55
+#define NOTE_AS1 58
+#define NOTE_B1  62
+#define NOTE_C2  65
+#define NOTE_CS2 69
+#define NOTE_D2  73
+#define NOTE_DS2 78
+#define NOTE_E2  82
+#define NOTE_F2  87
+#define NOTE_FS2 93
+#define NOTE_G2  98
+#define NOTE_GS2 104
+#define NOTE_A2  110
+#define NOTE_AS2 117
+#define NOTE_B2  123
+#define NOTE_C3  131
+#define NOTE_CS3 139
+#define NOTE_D3  147
+#define NOTE_DS3 156
+#define NOTE_E3  165
+#define NOTE_F3  175
+#define NOTE_FS3 185
+#define NOTE_G3  196
+#define NOTE_GS3 208
+#define NOTE_A3  220
+#define NOTE_AS3 233
+#define NOTE_B3  247
+#define NOTE_C4  262
+#define NOTE_CS4 277
+#define NOTE_D4  294
+#define NOTE_DS4 311
+#define NOTE_E4  330
+#define NOTE_F4  349
+#define NOTE_FS4 370
+#define NOTE_G4  392
+#define NOTE_GS4 415
+#define NOTE_A4  440
+#define NOTE_AS4 466
+#define NOTE_B4  494
+#define NOTE_C5  523
+#define NOTE_CS5 554
+#define NOTE_D5  587
+#define NOTE_DS5 622
+#define NOTE_E5  659
+#define NOTE_F5  698
+#define NOTE_FS5 740
+#define NOTE_G5  784
+#define NOTE_GS5 831
+#define NOTE_A5  880
+#define NOTE_AS5 932
+#define NOTE_B5  988
+#define NOTE_C6  1047
+#define NOTE_CS6 1109
+#define NOTE_D6  1175
+#define NOTE_DS6 1245
+#define NOTE_E6  1319
+#define NOTE_F6  1397
+#define NOTE_FS6 1480
+#define NOTE_G6  1568
+#define NOTE_GS6 1661
+#define NOTE_A6  1760
+#define NOTE_AS6 1865
+#define NOTE_B6  1976
+#define NOTE_C7  2093
+#define NOTE_CS7 2217
+#define NOTE_D7  2349
+#define NOTE_DS7 2489
+#define NOTE_E7  2637
+#define NOTE_F7  2794
+#define NOTE_FS7 2960
+#define NOTE_G7  3136
+#define NOTE_GS7 3322
+#define NOTE_A7  3520
+#define NOTE_AS7 3729
+#define NOTE_B7  3951
+#define NOTE_C8  4186
+#define NOTE_CS8 4435
+#define NOTE_D8  4699
+#define NOTE_DS8 4978
+#define REST     0
+
+// notes of the melody followed by the duration.
+// a 4 means a quarter note, 8 an eighteenth , 16 sixteenth, so on
+// !!negative numbers are used to represent dotted notes,
+// so -4 means a dotted quarter note, that is, a quarter plus an eighteenth!!
+int melody[] = {
+
+  // Darth Vader theme (Imperial March) - Star wars
+  // Score available at https://musescore.com/user/202909/scores/1141521
+  // The tenor saxophone part was used
+
+  NOTE_A4,-4, NOTE_A4,-4, NOTE_A4,16, NOTE_A4,16, NOTE_A4,16, NOTE_A4,16, NOTE_F4,8, REST,8,
+  NOTE_A4,-4, NOTE_A4,-4, NOTE_A4,16, NOTE_A4,16, NOTE_A4,16, NOTE_A4,16, NOTE_F4,8, REST,8,
+  NOTE_A4,4, NOTE_A4,4, NOTE_A4,4, NOTE_F4,-8, NOTE_C5,16,
+
+  NOTE_A4,4, NOTE_F4,-8, NOTE_C5,16, NOTE_A4,2,//4
+  NOTE_E5,4, NOTE_E5,4, NOTE_E5,4, NOTE_F5,-8, NOTE_C5,16,
+  NOTE_A4,4, NOTE_F4,-8, NOTE_C5,16, NOTE_A4,2,
+
+  NOTE_A5,4, NOTE_A4,-8, NOTE_A4,16, NOTE_A5,4, NOTE_GS5,-8, NOTE_G5,16, //7
+  NOTE_DS5,16, NOTE_D5,16, NOTE_DS5,8, REST,8, NOTE_A4,8, NOTE_DS5,4, NOTE_D5,-8, NOTE_CS5,16,
+
+  NOTE_C5,16, NOTE_B4,16, NOTE_C5,16, REST,8, NOTE_F4,8, NOTE_GS4,4, NOTE_F4,-8, NOTE_A4,-16,//9
+  NOTE_C5,4, NOTE_A4,-8, NOTE_C5,16, NOTE_E5,2,
+
+  NOTE_A5,4, NOTE_A4,-8, NOTE_A4,16, NOTE_A5,4, NOTE_GS5,-8, NOTE_G5,16, //7
+  NOTE_DS5,16, NOTE_D5,16, NOTE_DS5,8, REST,8, NOTE_A4,8, NOTE_DS5,4, NOTE_D5,-8, NOTE_CS5,16,
+
+  NOTE_C5,16, NOTE_B4,16, NOTE_C5,16, REST,8, NOTE_F4,8, NOTE_GS4,4, NOTE_F4,-8, NOTE_A4,-16,//9
+  NOTE_A4,4, NOTE_F4,-8, NOTE_C5,16, NOTE_A4,2,
+
+};

RadioLib/examples/AFSK/AFSK_Tone/AFSK_Tone.ino

@@ -0,0 +1,92 @@
+/*
+  RadioLib AFSK Example
+
+  This example shows hot to send audio FSK tones
+  using SX1278's FSK modem.
+
+  Other modules that can be used for AFSK:
+  - SX127x/RFM9x
+  - RF69
+  - SX1231
+  - CC1101
+  - Si443x/RFM2x
+  - SX126x/LLCC68
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// SX1278 has the following connections:
+// NSS pin:   10
+// DIO0 pin:  2
+// RESET pin: 9
+// DIO1 pin:  3
+SX1278 radio = new Module(10, 2, 9, 3);
+
+// create AFSK client instance using the FSK module
+// this requires connection to the module direct
+// input pin, here connected to Arduino pin 5
+// SX127x/RFM9x:  DIO2
+// RF69:          DIO2
+// SX1231:        DIO2
+// CC1101:        GDO2
+// Si443x/RFM2x:  GPIO
+// SX126x/LLCC68: DIO2
+AFSKClient audio(&radio, 5);
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize SX1278 with default settings
+  Serial.print(F("[SX1278] Initializing ... "));
+  int state = radio.beginFSK();
+
+  // when using one of the non-LoRa modules for AFSK
+  // (RF69, CC1101, Si4432 etc.), use the basic begin() method
+  // int state = radio.begin();
+
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize AFSK client
+  Serial.print(F("[AFSK] Initializing ... "));
+  state = audio.begin();
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  // AFSKClient can be used to transmit tones,
+  // same as Arduino tone() function
+  
+  // 400 Hz tone
+  Serial.print(F("[AFSK] 400 Hz tone ... "));
+  audio.tone(400);
+  delay(1000);
+
+  // silence
+  Serial.println(F("done!"));
+  audio.noTone();
+  delay(1000);
+
+  // AFSKClient can also be used to transmit HAM-friendly
+  // RTTY, Morse code, Hellschreiber, SSTV and AX.25.
+  // Details on how to use AFSK are in the example
+  // folders for each of the above modes.
+}

RadioLib/examples/AFSK/AFSK_Tone_AM/AFSK_Tone_AM.ino

@@ -0,0 +1,101 @@
+/*
+  RadioLib AM-modulated AFSK Example
+
+  This example shows hot to send AM-modulated
+  audio FSK tones using SX1278's OOK modem.
+
+  Other modules that can be used for AFSK:
+  - SX127x/RFM9x
+  - RF69
+  - SX1231
+  - CC1101
+
+  For default module settings, see the wiki page
+  https://github.com/jgromes/RadioLib/wiki/Default-configuration
+
+  For full API reference, see the GitHub Pages
+  https://jgromes.github.io/RadioLib/
+*/
+
+// include the library
+#include <RadioLib.h>
+
+// SX1278 has the following connections:
+// NSS pin:   10
+// DIO0 pin:  2
+// RESET pin: 9
+SX1278 radio = new Module(10, 2, 9);
+
+// create AFSK client instance using the FSK module
+// this requires connection to the module direct
+// input pin, here connected to Arduino pin 5
+// SX127x/RFM9x:  DIO2
+// RF69:          DIO2
+// SX1231:        DIO2
+// CC1101:        GDO2
+AFSKClient audio(&radio, 5);
+
+void setup() {
+  Serial.begin(9600);
+
+  // initialize SX1278 with default settings
+  Serial.print(F("[SX1278] Initializing ... "));
+  int state = radio.beginFSK();
+
+  // when using one of the non-LoRa modules for AFSK
+  // (RF69, CC1101, Si4432 etc.), use the basic begin() method
+  // int state = radio.begin();
+
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // initialize AFSK client
+  Serial.print(F("[AFSK] Initializing ... "));
+  state = audio.begin();
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+
+  // after that, set mode to OOK
+  Serial.print(F("[SX1278] Switching to OOK ... "));
+  state = radio.setOOK(true);
+  if(state == RADIOLIB_ERR_NONE) {
+    Serial.println(F("success!"));
+  } else {
+    Serial.print(F("failed, code "));
+    Serial.println(state);
+    while (true) { delay(10); }
+  }
+}
+
+void loop() {
+  // AFSKClient can be used to transmit tones,
+  // same as Arduino tone() function
+
+  // 400 Hz tone
+  Serial.print(F("[AFSK] 400 Hz tone ... "));
+  audio.tone(400);
+  delay(1000);
+
+  // silence
+  Serial.println(F("done!"));
+  audio.noTone();
+  delay(1000);
+
+  // AFSKClient can also be used to transmit HAM-friendly
+  // RTTY, Morse code, Hellschreiber, SSTV and AX.25.
+  // Details on how to use AFSK are in the example
+  // folders for each of the above modes.
+
+  // CAUTION: Unlike standard AFSK, the result when using OOK
+  // must be demodulated as AM!
+}